窩窩論壇上我們每天都會(huì)發(fā)布excel練習(xí)題給窩友們學(xué)習(xí)，在出題時(shí)，經(jīng)常會(huì)遇到模擬隨機(jī)生成姓名和數(shù)據(jù)。

　　數(shù)字可以使用rand、RANDBETWEEN函數(shù)來(lái)隨機(jī)生成�？墒切彰�如何弄呢，本文介紹使用VBA自動(dòng)隨機(jī)生成姓名。

　　具體的隨機(jī)生成姓名如下介紹：

　　第一步，新建一個(gè)excel工作薄

　　這個(gè)工作薄里面包含兩個(gè)工作表，分別是“姓名數(shù)據(jù)”和“生成隨機(jī)姓名”。

　　其中的“姓名數(shù)據(jù)”工作表，有三列數(shù)據(jù)：百家姓、男子名、女子名，是我們之前已經(jīng)輸入好了的。

　　第二步，切換到“生成隨機(jī)姓名”工作表，單擊“生成隨機(jī)姓名”按鈕，excel會(huì)出現(xiàn)一個(gè)輸入框，提示我們輸入要生成的人名數(shù)。比如我們輸入100，單擊“確定”，此工作表A列就會(huì)隨機(jī)生成姓名100個(gè)。

　　下面提供隨機(jī)生成姓名的VBA代碼，使用方法是按下ALT+F11組合鍵，打開(kāi)VBE編輯器，插入——模塊，復(fù)制下面的代碼，然后為了操作方便，我們?cè)凇吧�成隨機(jī)姓名”工作表中插入了一個(gè)按鈕，將這段代碼指定給按鈕。

Sub 隨機(jī)生成姓名()
Dim Arr, Arr2, Arr3, I%, N&, S As BooLEAN, Str$, Dic, A&, B&
N = Val(InputBox("請(qǐng)輸入要生成的人名數(shù)："))     '輸入要生成的隨機(jī)人名數(shù)量
If N = 0 Then Exit Sub      '如果未輸入或點(diǎn)了取消則退出程序
Set Dic = CreateObject("scripting.dictionary")  '創(chuàng)建字典項(xiàng)目，用于清除生成的重復(fù)的人名
With Sheet1     '從sheet1中讀取數(shù)據(jù)并隨機(jī)生成姓名
    Arr = .Range(.[a2], .Cells(.Rows.Count, 1).End(3))  '讀取百家姓放入數(shù)組
    Arr2 = .Range(.[b2], .Cells(.Rows.Count, 2).End(3))    '讀取男子名常用字放入數(shù)組
    Arr3 = .Range(.[c2], .Cells(.Rows.Count, 3).End(3))     '讀取女子名常用字放入數(shù)組
    Do  '循環(huán)執(zhí)行
        Str = ""       '先清空用于存儲(chǔ)生成的名字的變量
        S = Rnd > 0.5   '用取得的隨機(jī)數(shù)來(lái)判斷生成男子名還是女子名
        I = 2 + IIf(Rnd > 0.8, 0, 1)    '用隨機(jī)數(shù)確定生成的名字的字符數(shù)（80%的幾率為三個(gè)字）
        If S Then   '如果是男子名，則
            A = Int(Rnd * (UBound(Arr) - 2)) + 2    '取得姓對(duì)應(yīng)的數(shù)組下標(biāo)
            B = Int(Rnd * (UBound(Arr2) - 2)) + 2   '取得名字的對(duì)應(yīng)下數(shù)組下標(biāo)
            Str = Arr(A, 1) & Arr2(B, 1)    '串接名字
            If I > 2 Then   '如果名字的字符數(shù)大于2，則再得一次名字的字符下標(biāo)并串接給字符串變量
                B = Int(Rnd * (UBound(Arr2) - 2)) + 2
                Str = Str & Arr2(B, 1)
            End If
        Else    '如果是女子名，則取對(duì)應(yīng)的女子名數(shù)組內(nèi)容，處理方式同上
            A = Int(Rnd * (UBound(Arr) - 2)) + 2
            B = Int(Rnd * (UBound(Arr3) - 2)) + 2
            Str = Arr(A, 1) & Arr3(B, 1)
            If I > 2 Then
                B = Int(Rnd * (UBound(Arr3) - 2)) + 2
                Str = Str & Arr3(B, 1)
            End If
        End If
        Dic(Str) = ""   '將隨機(jī)姓名放入字典中
    Loop Until Dic.Count = N    '如果字典項(xiàng)目數(shù)量達(dá)到輸入的數(shù)值則跳出循環(huán)
End With
With Sheet2     '將結(jié)果寫入sheet2中
    .Cells.Clear    '清空原有內(nèi)容
    If Dic.Count > 65536 Then   '防止數(shù)量太多時(shí)無(wú)法轉(zhuǎn)置及數(shù)據(jù)超出單元格最大行號(hào)的情況
        Arr = Dic.keys
        For N = LBound(Arr) To UBound(Arr)
            Cells((N Mod 65536) + 1, N \ 65536 + 1) = Arr(N)
        Next N
    Else    '數(shù)量少時(shí)直接轉(zhuǎn)置
        .[a1].Resize(Dic.Count, 1) = Application.Transpose(Dic.keys)    '轉(zhuǎn)置字典的keys值
    End If
End With
Set Dic = Nothing   '清空字典項(xiàng)目
End Sub

核心關(guān)注：拓步ERP系統(tǒng)平臺(tái)是覆蓋了眾多的業(yè)務(wù)領(lǐng)域、行業(yè)應(yīng)用，蘊(yùn)涵了豐富的ERP管理思想，集成了ERP軟件業(yè)務(wù)管理理念，功能涉及供應(yīng)鏈、成本、制造、CRM、HR等眾多業(yè)務(wù)領(lǐng)域的管理，全面涵蓋了企業(yè)關(guān)注ERP管理系統(tǒng)的核心領(lǐng)域，是眾多中小企業(yè)信息化建設(shè)首選的ERP管理軟件信賴品牌。

轉(zhuǎn)載請(qǐng)注明出處：拓步ERP資訊網(wǎng)http://www.ezxoed.cn/

本文標(biāo)題：利用excel中vba代碼隨機(jī)生成姓名列表的方法

本文網(wǎng)址：http://www.ezxoed.cn/html/support/11139213451.html